Running the Master Tracks software with the debugger shows that it's still reading the midi data but the program seems to stop updating the screen and responding to key strokes:

./mame64 apple2e -sl2 midi -verbose -flop1 ../../Passport\ designs\ -\ Master\ tracks\ v1.8.dsk -snapsize 560x384 -debug -midiin "Portable Grand MIDI 1" -midiout "Portable Grand MIDI 1"


I thought I'd see what registers were being read.

Code
wp c0a0,10,rw,1,{printf "pc=%x wpaddr=%x wpdata=%x a=%x",pc,wpaddr,wpdata,a; g}

Error in command: {printf "pc=%x wpaddr=%x wpdata=%x a=%x",pc,wpaddr,wpdata,a; g}

                  ^unknown command

So what was wrong with my wpset debugger command? An extra space at the end of the line... It says unknown command but doesn't tell you why exactly.



Master Tracks freezes up within just a few seconds, but hitting CTRL+F12 for reset brings it back, and if you set the track to play (F for format, then P for play) and space to start playback, it will play the first few notes it recorded before it froze up.

[Linked Image from i.imgur.com][Linked Image from i.imgur.com]


[Linked Image from i.imgur.com]


Are there any other midi programs for the Apple IIe?


Just for fun, I thought I'd type in the little Applesoft Demo program for the Passport Midi Card from the manual and fix some of the mistakes:


Code
emu.keypost([[
100 REM ------------------------------
110 REM - MIDI DATA PLAYBACK DEMO    -
120 REM -APPLESOFT BASIC-
130 REM -(C)1984 PASSPORT DESIGNS INC-
140 REM -ALL RIGHTS RESERVED-
150 REM --
160 REM - VERSIOM 1.19/6/84 -
170 REM -PROGRAMMER: BRUCE BETHKE-
200 REM -----------------------------
210 REM
220 GOSUB 2000: REM DRAW SCREEN
230 GOSUB 3000: REM DEFINE VARIABLES
235 GOTO 1000: REM BEGIN PLAYBACK
240 REM
250 REM
260 REM -----------------------------
270 REM -SUBROUTINES-
280 REM -----------------------------
290 REM
300 REM -- WAIT FOR ACIA TO CLEAR ---
310 FOR TIM = 1 TO 4: NEXT : RETURN
320 REM
330 REM
400 REM —- WAIT FOR NOTES DURATION -—
410 FOR TIM = 1 TO 4: NEXT : RETURN
420 REM
430 REM
500 REM ------TURN OFF OLD NOTE ------
510 POKE AD,OFFKY: GOSUB 310
520 POKE AD,OLDKY: GOSUB 310
530 POKE AD,VOFF: GOSUB 310
540 RETURN
550 REM
560 REM
600 REM ----- TURN ON NEW NOTE -----
610 POKE AD,KEYDN: GOSUB 310
620 POKE AD,NEXKY: GOSUB 310
630 POKE AD,VMAX: GOSUB 310
640 RETURN
650 REM
660 REM
1000 REM --------------------------
1010 REM -BEGIN PLAYBACK—
1020 REM --------------------------
1030 REM
1040 FOR N = 1 TO 24
1050 READ NEXKY
1060 NEXKY = NEXKY + T: REM TRANSPOSE
1070 GOSUB 510: REM TURN OFF PREVIOUS NOTE
1080 GOSUB 610: REM PLAY CURRENT NOTE
1090 GOSUB 410: REM WAIT ONE NOTE’S DURATION
1100 OLDKY = NEXKY: REM CURRENT NOTE BECOMES PREVIOUS NOTE
1110 NEXT N: REM GET NEXT NOTE
1120 REM
1130 REM ----------------------------
1140 REM - AT END OF DATA, TURN OFF -
1150 REM - LAST NOTE PLAYED-
1160 REM ----------------------------
1175 GOSUB 410
1180 POKE AD,OFFKY: GOSUB 310
1190 POKE AD,OLDKY: GOSUB 310
1195 POKE AD,VOFF: GOSUB 310
1197 REM
1200 REM ----------------------------
1210 REM - EXIT / TRANSPOSE PROMPT -
1220 REM ----------------------------
1240 VTAB 12: HTAB 10
1250 PRINT “CONTINUE (Y/N)";: INPUT A$
1260 IF (A$ = “Y” OR A$ = "y") THEN 1300
1270 HOME : END
1290 REM
1300 REM ---- CONTINUE PLAYBACK ---
1310 VTAB 14: HTAB 3
1320 PRINT “TRANSPOSE VALUE (+/- 0...36)”;: INPUT A$
1330 T = VAL (A$)
1340 IF (T > = — 36) AND (T < = 36) THEN 1400
1350 HOME : GOSUB 2000: GOTO 1310
1360 REM
1400 RESTORE : GOTO 1040
1410 REM =======================
1500 REM
1900 REM
2000 REM -------------------------
2010 REM -DRAW SCREEN-
2020 REM -------------------------
2040 HOME : PRINT CHR$ (7): REM BEEP!
2050 VTAB 1: HTAB 7: INVERSE
2060 PRINT “MIDI PLAYBACK DEMONSTRATION”
2070 NORMAL
2080 VTAB 3: HTAB 5: INVERSE
2090 PRINT “(C) 1984 PASSPORT DESIGNS, INC.”
2100 NORMAL
2110 VTAB 5: HTAB 5: PRINT”**********************************"
2120 RETURN
2130 REM
2140 REM
3000 REM --------------------------
3010 REM -DEFINE VARIABLES—
3020 REM --------------------------
3030 REM
3040 REM ACIA CONTROL AND DATA REGISTERS
3050 REM WITH MIDI CARD IN SLOT#2
3060 AC = 49320: REM ACIA CONTROL
3070 AD = 49321: REM ACIA DATA
3080 OFFKY = 128: REM KEY OFF STATUS BYTE
3090 KEYDN = 144: REM KEY ON STATUS BYTE
3100 VOFF = 0: REM KEY VELOCITY 0
3110 VMAX = 127: REM KEY VELOCITY = 127
3120 OLDKY = 0: REM “OLD” KEY ID NUMBER
3130 NEXKY = 0: REM “NEW” KEY ID NUMBER
3140 DUR = 50 : REM NOTE DURATION
3150 T = 0    : REM TRANSPOSITION VALUE
3160 A$ = ““  : REM INPUT STRING VARIABLE
3180 REM
3200 REM ----------------------------
3210 REM -RESET & CONFIGURE ACIA-
3220 REM ----------------------------
3230 REM
3240 POKE AC,19: POKE AC,17
3250 RETURN
3300 REM
3400 REM
4000 REM ----------------------------
4010 REM - KEY ID (NOTE) DATA TABLE -
4020 REM ----------------------------
4030 REM
4040 DATA 60,61,62,63,64,65
4050 DATA 66,67,68,69,70,71
4060 DATA 72,71,69,68,67,66
4070 DATA 65,64,63,62,61,60
4080 REM
4090 REM
]])